This website is not affiliated with, sponsored by, or approved by SAP AG.

How to find available user exits for a Transaction?

Development (ABAP Development WorkBench, ABAP/4 programming)

Moderators: Snowy, thx4allthefish, YuriT, Gothmog

How to find available user exits for a Transaction?

Postby arksap » Mon Nov 10, 2003 11:28 pm

1) How to find if a user exit is available for a transaction and if so its name?

2) How to find out if any userexit is active in a transaction in say a production client?
arksap
 
Posts: 400
Joined: Tue Dec 17, 2002 10:23 pm
Location: California,US

user exit

Postby Shyam » Mon Nov 10, 2003 11:53 pm

USER EXITS CAN BE found out using transaction SMOD and in search criteria go ahead by development class
and then u need to do some exercise if there are many exits available
With warm regards,
Shyam
Shyam
 
Posts: 109
Joined: Sun Jan 26, 2003 8:09 am
Location: India

Re: user exit

Postby manohar » Tue Nov 11, 2003 6:05 am

Here is a small program which you will be used to find an exit for a given Tcode.
But for second question....even i want to know.

Code: Select all
report Y_FIND_USEREXIT no standard page heading . "test to delete
tables : tstc, tadir, modsapt, modact, trdir, tfdir, enlfdir.
tables : tstct.
data : jtab like tadir occurs 0 with header line.
data : field1(30).
data : v_devclass like tadir-devclass.
parameters : p_tcode like tstc-tcode obligatory.
select single * from tstc where tcode eq p_tcode.
if sy-subrc eq 0.
  select single * from tadir where pgmid = 'R3TR'
                               and object = 'PROG'
                               and obj_name = tstc-pgmna.
  move : tadir-devclass to v_devclass.
  if sy-subrc ne 0.
    select single * from trdir where name = tstc-pgmna.
    if trdir-subc eq 'F'.
      select single * from tfdir where pname = tstc-pgmna.
      select single * from enlfdir where funcname = tfdir-funcname.
      select single * from tadir where pgmid = 'R3TR'
                                   and object = 'FUGR'
                                   and obj_name eq enlfdir-area.
      move : tadir-devclass to v_devclass.
    endif.
  endif.
  select * from tadir into table jtab where pgmid = 'R3TR'
                        and object = 'SMOD'
                        and devclass = v_devclass.
  select single * from tstct where sprsl eq sy-langu and
                                   tcode eq p_tcode.
  format color col_positive intensified off.
  write:/(19) 'Transaction Code - ',
       20(20) p_tcode,
       45(50) tstct-ttext.
  skip.
  if not jtab[] is initial.
    write:/(95) sy-uline.
    format color col_heading intensified on.
    write:/1 sy-vline,
           2 'Exit Name',
          21 sy-vline ,
          22 'Description',
          95 sy-vline.
    write:/(95) sy-uline.
    loop at jtab.
      select single * from modsapt where sprsl = sy-langu and
                                         name = jtab-obj_name.
      format color col_normal intensified off.
      write:/1 sy-vline,
             2 jtab-obj_name hotspot on,
            21 sy-vline ,
            22 modsapt-modtext,
            95 sy-vline.
    endloop.
    write:/(95) sy-uline.
    describe table jtab.
    skip.
    format color col_total intensified on.
    write:/ 'No of Exits:' , sy-tfill.
  else.
    format color col_negative intensified on.
    write:/(95) 'No User Exit exists'.
  endif.
else.
  format color col_negative intensified on.
  write:/(95) 'Transaction Code Does Not Exist'.
endif.

at line-selection.
  get cursor field field1.
  check field1(4) eq 'JTAB'.
  set parameter id 'MON' field sy-lisel+1(10).
  call transaction 'SMOD' and skip first   screen.
Best Regards
Manohar
manohar
 
Posts: 168
Joined: Sun Oct 20, 2002 10:50 pm
Location: Bangalore, India.

Re: How to find available user exits for a Transaction?

Postby Rich » Tue Nov 11, 2003 7:43 am

arksap wrote:2) How to find out if any userexit is active in a transaction in say a production client?


You can find the activation status of a user exit by looking in SMOD in the components option. If the exit is activated it will have a green tick or a green blob next to it. (I'm not on SAP at the moment...)
Regards

Rich

Image
Abap KC:http://www.richard-harper.me.uk/Kb
SFMDR:http://www.se37.com
Rich
 
Posts: 7112
Joined: Thu Oct 31, 2002 4:47 pm
Location: Liverpool

Postby CLYDEBASSIE » Sun Sep 19, 2004 7:55 pm

I believe you may go to CMOD to check activated user exits.
break clydebassie.
CLYDEBASSIE
 
Posts: 695
Joined: Tue Nov 25, 2003 7:24 pm
Location: Wherever work is..

Re:

Postby Sap Guest » Wed Dec 01, 2004 1:39 am

One Easiest way to find the User exits ,Get the program name of the transaction and Search in SE37
Eg : Userexit_<Progam name>*
Sap Guest
 

Ignore previous mail

Postby SAP Guest » Wed Dec 01, 2004 2:01 am

One Easiest way to find the User exits ,Get the program name of the transaction and Search in SE37
Eg : Exit_<Progam name>*
SAP Guest
 

i'll add my input since i see nobody has mentioned it

Postby clekchau2 » Wed Mar 02, 2005 8:02 pm

goto se81

go to specific area you want to find a user exit or badi for

select the area, will turn yellow

choose information system button.

select environment/exit techniques/customer exits/enhancements

select business add ins or customer exits, will show you all enhancements associated by package
clekchau2
 

Postby Angry God » Thu Mar 03, 2005 4:42 am

Shortcut to the above:

SE80
Select Repository Information System
Click Enhancements
Click Business Add-Ins or Customer Exits
Angry God
 

Postby Angry God » Thu Mar 03, 2005 4:51 am

Actually I'm not sure this method picks up all user-exits.

For example: include RV61AFZA is designed for user-exits, package VMOD, but it doesn't show up in the RIS.
Angry God
 

Postby abapmaster » Thu Feb 22, 2007 8:56 am

Just to add on this, SAP ISU or the other new versions has events based modifications.

The Transaction to find particular even is /nFQEVENTS.
ABAPmaster.com
Inspired. Innovative. Dedicated

http://www.abapmaster.com
abapmaster
 
Posts: 5
Joined: Tue Feb 20, 2007 4:48 am

Postby PJA » Fri Feb 23, 2007 5:32 am

Try here

PeteA
PJA
 
Posts: 11383
Joined: Sun Jul 20, 2003 3:11 pm
Location: Deepest darkest Aberdeenshire


Return to ABAP

Who is online

Users browsing this forum: No registered users and 6 guests





loading...


This website is not affiliated with, sponsored by, or approved by SAP AG.